!Read topologie
open read card unit 10 name "$CHARMMDATA/top_all22_prot_cmap.inp"
read rtf card unit 10
!Read parameters
open read card unit 20 name "$CHARMMDATA/par_all22_prot_cmap.inp"
read para card unit 20
read sequence card
* sequence of phospholamban protein
*
16
! 1 2 3 4 5 6 7 8 9 10
GLY TRP TRP LEU ALA LEU ALA LEU ALA LEU
ALA LEU ALA TRP TRP ALA
generate PRO0 setup first ACE last CT3
ic param
ic seed 1 N 1 CA 1 C
ic build
hbuild
coor stat
coor orie
coor stat
NBOND atom switch cdie vdw vswitch bycb -
ctonnb 20.0 ctofnb 20.0 cutnb 24.0
mini sd nstep 100 nprint 10 step 0.005 inbfrq -1 imgfrq -1
mini abnr nstep 100 nprint 10 step 0.005 inbfrq -1 imgfrq -1
coor stat
coor orie
coor state
coor rotate ydir 1.0 phi 90.0
coor state
open write card unit 10 name pept.pdb
write coor pdb unit 10
close unit 10
coor init
coor stat select type CA end
set ntot = ?nsel
set i = 1
label ic_edit
calc j = @i - 1
calc k = @i + 1
if j .ge. 1 then
IC EDIT
DIHE @j C @i N @i CA @i C -65.0 ! PHI
END
endif
if k .le. @ntot then
IC EDIT
DIHE @i N @i CA @i C @k N -40.0 ! PSI
END
endif
incr i by 1
if i .le. @ntot goto ic_edit
ic param
ic seed 1 N 1 CA 1 C
ic build
mini sd nstep 100 nprint 10 step 0.005 inbfrq -1 imgfrq -1
mini abnr nstep 100 nprint 10 step 0.005 inbfrq -1 imgfrq -1
open write card unit 10 name helix.pdb
write coor pdb unit 10
close unit 10
stop
